各式珍藏巨集語法存放
🔍前提邏輯
。背包道具座標（註：先背包後欄位，例：/use 藍 紅）
。語法中英對譯（PTT參考資料）
/cast = /施放
/use = /使用
/run = /跑
/dismount = /下馬
/target = /tar = /目標
。條件式
[mounted] = 已上馬
[button:1]／[btn:1] = 左鍵點擊
[button:2]／[btn:2] = 右鍵點擊
[flyable] ／[noflyable] = 可飛行區域／不可飛行區域
[combat]／[nocombat] = 戰鬥中／非戰鬥狀態
[exists]／[noexists] = (目標)存在／不存在
[dead] = (目標)已死亡
[group]／[nogroup] = 有組隊／無組隊
[@pet]／[@focus] = 以寵物為目標／以專注對象為目標
[@mouseover] = 以游標指示對象為目標
[help] = 當前目標為友方
。其他參考資料
[翻译/工具]猎人全技能中文简/繁/英文对照表(添加宠物技能中英对照表)
[有用] 巨集 縮減
🌐通用
。任務介面字體放大（20為字體大小）
/run QuestFont:SetFont("Fonts\\bLEI00D.TTF",20,"")
。播放坐騎特效（可用來觀賞飛行坐騎的特效）
/坐騎特效
。召喚指定坐騎（不同鍵點擊對應不同坐騎）
#showtooltip 柯爾克隆戰狼
/cast [modifier:ctrl] X-53型觀光火箭
/cast [modifier:alt] 巨大冰原長毛象
/cast [modifier:shift] 旅者的凍原長毛象
/cast [btn:1] 柯爾克隆戰狼
/cast [btn:2] 機械重機車
。照順序召喚指定坐騎
#showtooltip 漫行古樹
/castsequence 脈織飛毯,秘法師的法力刃豹,青銅龍,黑瑪瑙色虛空之翼龍,渦輪飛行器,紫色元龍,鬼靈蠍尾獅,商隊土狼
。左鍵隨機召喚指定坐騎；右鍵召喚特定坐騎；上馬狀態純下馬
#showtooltip 旅者的凍原長毛象
/dismount
/stopmacro [mounted]
/cast [btn:2] 旅者的凍原長毛象
/castrandom [btn:1] 霜狼嗥叫者,大型啤酒節科多獸,黑色作戰科多獸,柯爾克隆戰狼,奧格瑪狼騎,迅捷啤酒節山羊,恐狼,夜裔法力刃豹,秘法師的法力刃豹,高嶺雷蹄鹿
#showtooltip 釣魚
/cast [button:2] 烹飪; 釣魚
。左鍵施放勘查、右鍵開啟考古學選單
#showtooltip 勘察
/cast [button:2] 考古學
/cast [button:1] 勘察
。左右鍵使用不同爐石
#showtooltip
/use [btn:1] 新年長者的爐石
/use [btn:2] 永恆旅人的爐石
。倒數喊話（/P =隊伍頻道）（*疑似已失效）
/in 0 /P 3
/in 1 /P 2
/in 2 /P 1
/in 3 /P 跳
。增加視角最遠距離
/script SetCVar("cameraDistanceMaxFactor", 4)
/console SET targetNearestDistance "50"
/console SET targetNearestDistanceRadius "30"
。在畫面中上方顯示當前座標
/run local p,f="player",CreateFrame("Button",nil,UIParent,"OptionsButtonTemplate")f:SetPoint("TOP",0,0)f:SetScript("OnUpdate",function(s,e)x,y=C_Map.GetPlayerMapPosition(C_Map.GetBestMapForUnit(p),p):GetXY()f:SetText(format("%.2f %.2f",x*100,y*100))end)
🐺狼人專用
。不可飛行區域使用[野性奔跑]、飛行區域使用[隨機召喚喜愛的坐騎]
#showtooltip 野性奔跑
/cast [noflyable] 野性奔跑(種族特長)
/click [flyable] MountJournalSummonRandomFavoriteButton
🐾獵人專用
。用背包指定位置的食物餵食寵物+文字喊話
#showtooltip 0 1
/cast 餵養寵物
/use 0 1
/run SendChatMessage("餵食了 "..UnitName("pet").." ", "emote")
。對寵物使用指定位置的道具（將該道具設定為按鍵圖示&說明）（例如使用繃帶等）
#showtooltip 0 4
/target pet
/use [pet] 0 4
/targetlasttarget
。戰鬥時治療寵物；死亡則復活寵物；非戰時寵物撿骨；右鍵單純治療寵物
[正式版]
#showtooltip [combat] 治療寵物;[@pet,dead] 復活寵物;[@pet,exists,nocombat] 取物
/cast [combat] 治療寵物; [@pet,dead] 復活寵物; [btn:2] 治療寵物
/stopmacro [combat]
/cast [@pet,noexists][@pet,dead] 復活寵物 ; [@pet,exists,nocombat] 取物
[經典版]
#showtooltip [@pet,noexists][@pet,dead] 復活寵物; 治療寵物(等級 1)
/cast [@pet,dead] 復活寵物; 治療寵物; [btn:2] 治療寵物
/stopmacro [combat]
/cast [@pet,noexists][@pet,dead] 復活寵物
。施放[獵人印記]並呼叫寵物攻擊(非組隊或組隊戰鬥狀態時)+文字喊話；右鍵單純施放技能
#showtooltip 獵人印記/cast [btn:2] 獵人印記/stopmacro [btn:2]/cast 獵人印記/寵物攻擊 [combat]/stopmacro [group]/寵物攻擊/script SendChatMessage("呼叫【"..UnitName("pet").."】攻擊《".. UnitName("target").."》", "emote")
。同時施放[假死](玩家)&[裝死](寵物)；右鍵單獨施放[裝死](寵物)
#showtooltip 假死
/cast [btn:2] 裝死
/cast [btn:1] 假死
/cast [btn:1] 裝死
。對寵物施放[誤導]+文字喊話；右鍵單純施放[誤導]
#showtooltip 誤導
/cast [button:2] 誤導
/cast [@pet,exists,help] 誤導
/stopmacro [@pet,noexists][@pet,dead]
/script SendChatMessage("對【"..UnitName("pet").."】施放誤導。目標《"..UnitName("target").."》","emote")
。對友方專注目標施放[誤導]+文字喊話
#showtooltip 誤導
/cast [@focus,exists,help] 誤導
/stopmacro [@focus,noexists][@focus,dead]
/script SendChatMessage("對【"..UnitName("focus").."】施放誤導。目標《"..UnitName("target").."》","emote")
。對友方專注目標施放[誤導]+文字喊話，非組隊時將寵物設為專注目標
#showtooltip 誤導
/focus [target=focus,noexists][nogroup] pet
/cast [@focus,exists,help] 誤導
/stopmacro [@focus,noexists][@focus,dead]
/script SendChatMessage("對【"..UnitName("focus").."】施放誤導。目標《"..UnitName("target").."》","emote")
。對游標指向對象施放[誤導]+文字喊話；右鍵單純施放[誤導]
#showtooltip 誤導
/cast [button:2] 誤導
/cast [@mouseover,exists,help] 誤導
/stopmacro [@mouseover,noexists][@mouseover,dead]
/script SendChatMessage("對【"..UnitName("mouseover").."】施放誤導。目標《"..UnitName("target").."》","emote")
🌀薩滿專用
。施放[鬼魂之狼]的同時文字喊話（增加RPG氣氛）
#showtooltip 鬼魂之狼
/cast 鬼魂之狼
/script y=0;for i=1,40 do local x=UnitBuff("player",i);if x=="鬼魂之狼" then y=1;end;end;if y<1 then SendChatMessage("偉大的迅狼之靈啊，向您致意，請賦予我您的速度吧！","SAY");SendChatMessage("被迅狼之靈附身了！","EMOTE");end;
沒有留言:
張貼留言